Skip to content

net-libs/libktorrent: new package, add 25.08.0 #601

New issue

Have a question about this project? Sign up for a free GitHub account to open an issue and contact its maintainers and the community.

Sign up for GitHub

By clicking “Sign up for GitHub”, you agree to our terms of service and privacy statement. We’ll occasionally send you account related emails.

Already on GitHub? Sign in to your account

Open
CyberTailor wants to merge 1 commit into
base: master
Choose a base branch
from
Open

net-libs/libktorrent: new package, add 25.08.0 #601

Show file tree
Hide file tree
Changes from all commits
Commits
Show all changes
1 commit
Select commit
File filter

Filter by extension

Filter by extension
Conversations
Failed to load comments.
Loading
Jump to
Jump to file
Failed to load files.
Loading
Diff view
Diff view
1 change: 1 addition & 0 deletions net-libs/libktorrent/Manifest
View file
Open in desktop
Original file line number Diff line number Diff line change
@@ -0,0 +1 @@
DIST libktorrent-25.08.0.tar.xz 607140 BLAKE2B b5a7a75e4c42fc96b8b8154382af77bf265c7a4df9dd89290506de24bb0faa4d941383570ad7ab59141f010a630a92f67f0ab39aa25f1aafcb25ea1f1357aa31 SHA512 b677669791155598b947acc025bb74e3633ef988badfa3558b2ef6d6f1e090cd3944cee37133d8574507bd3a343b3c173fc3c9c8683595d13fa3bd1befb4e386
66 changes: 66 additions & 0 deletions net-libs/libktorrent/libktorrent-25.08.0.ebuild
View file
Open in desktop
Original file line number Diff line number Diff line change
@@ -0,0 +1,66 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

ECM_TEST="forceoptional"
KDE_ORG_CATEGORY="network"
KFMIN=6.16.0
QTMIN=6.9.1
inherit ecm gear.kde.org

DESCRIPTION="BitTorrent library based on KDE Frameworks"
HOMEPAGE="https://apps.kde.org/ktorrent/ https://userbase.kde.org/KTorrent"

LICENSE="GPL-2+"
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
IUSE="xfs"

COMMON_DEPEND="
>=app-crypt/qca-2.3.7:2[qt6(+)]
>=dev-libs/gmp-6.0.0a:0=
dev-libs/libgcrypt:0=
>=dev-qt/qtbase-${QTMIN}:6[network,xml]
>=kde-frameworks/karchive-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/solid-${KFMIN}:6
xfs? ( sys-fs/xfsprogs )
"
DEPEND="${COMMON_DEPEND}
>=dev-libs/boost-1.71
"
RDEPEND="${COMMON_DEPEND}
!dev-libs/botan[gmp(-)]
"
BDEPEND="sys-devel/gettext"

src_prepare() {
ecm_src_prepare

# Gentoo workaround because gmp.h in MULTILIB_WRAPPED_HEADERS is breaking this
sed -i -e "/^find_package/ s/\"\${LibGMP_MIN_VERSION}\" //" \
CMakeLists.txt || die
sed -i -e "/^find_dependency/ s/ \"@LibGMP_MIN_VERSION@\"//" \
KTorrent6Config.cmake.in || die
}

src_configure() {
local mycmakeargs=(
-DUSE_CRYPTO_BACKEND=LibGcrypt
-DWITH_XFS=$(usex xfs)
)
ecm_src_configure
}

src_test() {
# failing network tests
local myctestargs=(
-E "(fin|packetloss|send|superseedtest|transmit|utppolltest)"
)
ecm_src_test
}
14 changes: 14 additions & 0 deletions net-libs/libktorrent/metadata.xml
View file
Open in desktop
Original file line number Diff line number Diff line change
@@ -0,0 +1,14 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="project">
<email>kde@gentoo.org</email>
<name>Gentoo KDE Project</name>
</maintainer>
<upstream>
<bugs-to>https://bugs.kde.org/</bugs-to>
</upstream>
<use>
<flag name="xfs">Enable XFS specific disk preallocation support via <pkg>sys-fs/xfsprogs</pkg></flag>
</use>
</pkgmetadata>