conflu/writeGridCENTAUR.f90 at master · wandadars/conflu · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
! ******************************************************************************
!
! $Id: writeGridCENTAUR.f90,v 1.1 2005/03/05 17:25:53 haselbac Exp $
!
! Filename: writeGridCENTAUR.F90
!
! Purpose: Write grid file from CENTAUR in binary double-precision format.
!
! Description:
!
! Input:
!
! Output:
!
! Notes:
!   1. Cell and node pointers are written as 0.
!
! Author: Andreas Haselbacher
!
! Copyright: (c) 2001 by the University of Illinois
!
! RCS Revision history:
!
!   $Log: writeGridCENTAUR.f90,v $
!   Revision 1.1  2005/03/05 17:25:53  haselbac
!   Initial revision
!
!   Revision 1.1  2003/03/07 15:26:34  haselbac
!   Initial revision
!
!
! ******************************************************************************

SUBROUTINE writeGridCENTAUR

  USE modError
  USE modGlobals
  USE modGrid

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Local variables
! ==============================================================================

  INTEGER :: i,idum,iFile,j
  CHARACTER*(MAX_STRING_LEN) :: caseName,iFileName

! ******************************************************************************
! Open file and read title
! ******************************************************************************

  WRITE(STDOUT,'(/,1X,A)') 'Writing CENTAUR grid file...'
  WRITE(STDOUT,'(3X,A)') 'Enter case name:'
  READ(STDIN,*) caseName

  iFile     = FILE_UNIT_GRID_INPUT
  iFileName = TRIM(caseName)//'.hyb.bin'

  OPEN(iFile,FILE=iFileName,FORM="UNFORMATTED",STATUS="UNKNOWN",IOSTAT=errorFlag)
  IF ( errorFlag /= NO_ERROR ) THEN
    CALL errorHandling(FILE_OPEN_ERROR,iFileName,errorFlag)
  END IF ! errorFlag

  WRITE(iFile) gridCENTAUR%title

! ==============================================================================
! Coordinates
! ==============================================================================

  WRITE(iFile) gridCENTAUR%nVert

  WRITE(STDOUT,'(3X,A)') 'Coordinates...'

  WRITE(iFile) ((gridCENTAUR%xyz(i,j),j=1,gridCENTAUR%nVert),i=1,3)

  idum = 0
  WRITE(iFile) (idum,i=1,gridCENTAUR%nVert)

! ==============================================================================
! Cell connectivity
! ==============================================================================

  WRITE(iFile) gridCENTAUR%nTets
  IF ( gridCENTAUR%nTets > 0 ) THEN
    WRITE(STDOUT,'(3X,A)') 'Tetrahedra...'
    WRITE(iFile) ((gridCENTAUR%tet2v(i,j),j=1,gridCENTAUR%nTets),i=1,4)
    WRITE(iFile) (idum,i=1,gridCENTAUR%nTets)
  END IF ! nTetrahedra

  WRITE(iFile) gridCENTAUR%nHexs
  IF ( gridCENTAUR%nHexs > 0 ) THEN
    WRITE(STDOUT,'(3X,A)') 'Hexahedra...'
    WRITE(iFile) ((gridCENTAUR%hex2v(i,j),j=1,gridCENTAUR%nHexs),i=1,8)
    WRITE(iFile) (idum,i=1,gridCENTAUR%nHexs)
  END IF ! nHexahedra

  WRITE(iFile) gridCENTAUR%nPris
  IF ( gridCENTAUR%nPris > 0 ) THEN
    WRITE(STDOUT,'(3X,A)') 'Prisms...'
    WRITE(iFile) ((gridCENTAUR%pri2v(i,j),j=1,gridCENTAUR%nPris),i=1,6)
    WRITE(iFile) (idum,i=1,gridCENTAUR%nPris)
  END IF ! nPrisms

  WRITE(iFile) gridCENTAUR%nPyrs
  IF ( gridCENTAUR%nPyrs > 0 ) THEN
    WRITE(STDOUT,'(3X,A)') 'Pyramids...'
    WRITE(iFile) ((gridCENTAUR%pyr2v(i,j),j=1,gridCENTAUR%nPyrs),i=1,5)
    WRITE(iFile) (idum,i=1,gridCENTAUR%nPyrs)
  END IF ! nPyramids

! ==============================================================================
! Boundary types
! ==============================================================================

  WRITE(STDOUT,'(3X,A)') 'Boundary information...'

  WRITE(ifile) gridCENTAUR%nBounds
  WRITE(ifile) ((gridCENTAUR%bInfo(i,j),j=1,gridCENTAUR%nBounds),i=1,3)

  WRITE(ifile) (gridCENTAUR%bName(i),i=1,gridCENTAUR%nBounds)

! ==============================================================================
! Boundary face connectivity
! ==============================================================================

  WRITE(iFile) gridCENTAUR%nBTris

  IF ( gridCENTAUR%nBTris > 0 ) THEN
    WRITE(STDOUT,'(3X,A)') 'Boundary triangles...'
    WRITE(iFile) ((gridCENTAUR%bTri2v(i,j),j=1,gridCENTAUR%nBTris),i=1,3)
  END IF ! gridCENTAUR

  WRITE(iFile) gridCENTAUR%nBQuads

  IF ( gridCENTAUR%nBQuads > 0 ) THEN
    WRITE(STDOUT,'(3X,A)') 'Boundary quadrilaterals...'
    WRITE(iFile) ((gridCENTAUR%bQuad2v(i,j),j=1,gridCENTAUR%nBQuads),i=1,4)
  END IF ! gridCENTAUR

! ******************************************************************************
! Close file
! ******************************************************************************

  CLOSE(iFile,IOSTAT=errorFlag)
  IF ( errorFlag /= NO_ERROR ) THEN
    CALL errorHandling(FILE_CLOSE_ERROR,iFileName,errorFlag)
  END IF

  WRITE(STDOUT,'(1X,A,/)') 'Grid file written successfully.'

! ******************************************************************************
! End
! ******************************************************************************

END SUBROUTINE writeGridCENTAUR