MicroStorage/build.gradle.kts at main · sophuric/MicroStorage · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
plugins {
    java
    alias(libs.plugins.fabric.loom)
    alias(libs.plugins.minotaur)
}

val modName = property("mod.name").toString()
val modId = property("mod.id").toString()
val modGroup = property("mod.group").toString()
val version = property("mod.version").toString()

base.archivesName = "${modId}-${version}"

loom {
    splitEnvironmentSourceSets()

    accessWidenerPath = file("src/main/resources/microstorage.classtweaker")

    mods.create(modId) {
        sourceSet(sourceSets.getByName("main"))
        sourceSet(sourceSets.getByName("client"))
    }
}

repositories {
    mavenCentral()

    exclusiveContent {
        forRepository {
            maven("https://maven.terraformersmc.com/") {
                name = "Terraformers"
            }
        }

        filter {
            includeGroup("com.terraformersmc")
        }
    }

    exclusiveContent {
        forRepository {
            maven("https://raw.githubusercontent.com/SolidBlock-cn/mvn-repo/main") {
                name = "SolidBlock"
            }
        }

        filter {
            includeGroup("pers.solid")
        }
    }

    exclusiveContent {
        forRepository {
            maven("https://maven.parchmentmc.org") {
                name = "ParchmentMC"
            }
        }

        filter {
            includeGroup("org.parchmentmc.data")
        }
    }
}

dependencies {
    minecraft(libs.minecraft)

    @Suppress("UnstableApiUsage")
    mappings(
        loom.layered {
            officialMojangMappings()
            parchment(libs.parchment)
        }
    )

    modImplementation(libs.fabric.loader)
    modImplementation(libs.fabric.api)
    modImplementation(libs.brrp)
}

tasks.processResources {
    val map = mapOf(
        "mod_id" to modId,
        "mod_version" to version,
        "fabric_loader_version" to libs.versions.fabric.loader.get(),
        "fabric_api_version" to libs.versions.fabric.api.get(),
        "minecraft_version" to libs.versions.minecraft.get(),
        "brrp_version" to libs.versions.brrp.get().replaceAfterLast("-", ""), // remove Minecraft version from mod version
    )

    inputs.properties(map)
    filesMatching("fabric.mod.json") { expand(map) }
}

java {
    withSourcesJar()

    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

tasks.withType<JavaCompile> {
    options.encoding = "UTF-8"
    options.release = 21
}

tasks.jar { from("LICENSE") { rename { "${it}_${base.archivesName.get()}" } } }

modrinth {
    token.set(System.getenv("MODRINTH_TOKEN"))
    projectId.set("microstorage")
    versionNumber.set(version)
    versionType.set("release")
    uploadFile.set(tasks.remapJar)
    loaders.add("fabric")
    dependencies {
        required.project("fabric-api")
        required.project("brrp")
    }
    syncBodyFrom = rootProject.file("README.md").readText()
}