autorider/lib.nix at master · pyproject-nix/autorider · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
{ pyproject-nix, lib, ... }:
let
  inherit (builtins)
    mapAttrs
    filter
    listToAttrs
    isString
    split
    concatMap
    ;
  inherit (lib)
    optionals
    unique
    getAttrFromPath
    importJSON
    optionalAttrs
    ;
  inherit (pyproject-nix.lib.pep508) parseString mkEnviron evalMarkers;
in
{

  /**
    Create overlay from generated metadata directory
    .
  */
  mkOverlay =
    path:
    {
      so-providers ? { },
    }:
    let
      data = importJSON path;

      packages = mapAttrs (
        name: overrideMeta:
        overrideMeta
        // optionalAttrs (overrideMeta ? build-systems) {
          build-systems = map parseString overrideMeta.build-systems;
        }
      ) (data.packages or { });

    in
    final: prev:
    let
      inherit (prev) python;
      inherit (final) pkgs;
      environ = mkEnviron python;

      so-providers' =
        (mapAttrs (
          so: provider:
          let
            provider' = filter isString (split "\\." provider);
          in
          getAttrFromPath provider' pkgs
        ) (data.so-providers or { }))
        // so-providers;

      lookupSonames =
        sonames:
        unique (
          concatMap (
            soname:
            let
              provider = so-providers'.${soname};
            in
            if provider != null then [ provider ] else [ ]
          ) sonames
        );

    in
    mapAttrs (
      name: overrideMeta:
      let
        drv = prev.${name};
        format = drv.passthru.format or "pyproject";
      in
      if format == "pyproject" then
        drv.overrideAttrs (old: {

          buildInputs =
            (old.buildInputs or [ ])
            # Add native dependencies
            ++ optionals (overrideMeta ? sdist-depends-so) (lookupSonames overrideMeta.sdist-depends-so);

          nativeBuildInputs =
            old.nativeBuildInputs
            # Add native build tooling
            ++ optionals (overrideMeta ? build-requires) (map (name: pkgs.${name}) overrideMeta.build-requires)
            # Add build systems
            ++ optionals (overrideMeta ? build-systems) (
              let
                selected = filter (
                  build-system: build-system.markers == null || evalMarkers environ build-system.markers
                ) overrideMeta.build-systems;
                spec = listToAttrs (
                  map (build-system: {
                    inherit (build-system) name;
                    value = build-system.extras;
                  }) selected
                );
              in
              final.resolveBuildSystem spec
            );
        })
      else if format == "wheel" then
        drv.overrideAttrs (old: {
          buildInputs =
            (old.buildInputs or [ ])
            # Add native dependencies
            ++ optionals (overrideMeta ? wheel-depends-so) (lookupSonames overrideMeta.wheel-depends-so);
        })
      else
        throw "Could not determine format for ${name}"
    ) packages;
}