autorider/default.nix at master · pyproject-nix/autorider · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
{
  pyproject-nix,
  uv2nix,
  lib,
  pyproject-build-systems,
}@inputs:
let
  workspace = uv2nix.lib.workspace.loadWorkspace { workspaceRoot = ./.; };
  overlay = workspace.mkPyprojectOverlay {
    sourcePreference = "wheel";
  };

in
{
  lib = import ./lib.nix inputs;

  packages = {
    autorider =
      { callPackage, callPackages, python }:
      let
        pythonSet =
          (callPackage pyproject-nix.build.packages {
            inherit python;
          }).overrideScope
            (
              lib.composeManyExtensions [
                (pyproject-build-systems.overlays.wheel or pyproject-build-systems.wheel)
                overlay
              ]
            );

        venv = pythonSet.mkVirtualEnv "autorider-env" workspace.deps.default;
        inherit (callPackages pyproject-nix.build.util { }) mkApplication;
      in
        mkApplication {
          inherit venv;
          package = pythonSet.autorider;
        };
  };
}