Failed assertion from 'boot.initrd.postResumeCommands'

[Expressive-Synapse]

Hello, Ive been using a btfs impermanence setup like whats shown in the readme for a few years now, but recently I tried to update my flake and got the follow error

error:
       Failed assertions:
       - systemd stage 1 does not support `boot.initrd.postResumeCommands`. Instead, create systemd services using the `boot.initrd.systemd.services` options, which has an API matching the stage 2 `systemd.services` options. Refer to `bootup(7)`, specifically the sections on "Bootup in the Initrd" and "System Manager Bootup", for information about when various units happen, and order services accordingly.

           Definitions:
           - /nix/store/94mak8iycx0l1clnnn1f0dxfg5l8gplq-source/hosts/Titanic/configuration.nix
Command 'nix --extra-experimental-features 'nix-command flakes' build --print-out-paths '/persist/NixOSDots#nixosConfigurations."Titanic".config.system.build.toplevel' --no-link' returned non-zero exit status 1.
[ble: exit 1]

Im afraid im not knowledgeable enough to properly fix this issue myself. Does anyone know what to do to resolve this?

[Doosty]

Apparently nixos now uses systemd services in initrd and not just a shellscript like before. This worked for me, snippet is from ElvishJerricco on NixOS matrix channel, i just added the impermanence script into it. Be advised that i did not test it thoroughly.

      boot.initrd.systemd = {
        services.impermance-btrfs-rolling-root = {
          description = "Archiving existing BTRFS root subvolume and creating a fresh one";
          # Specify dependencies explicitly
          unitConfig.DefaultDependencies = false;
          # The script needs to run to completion before this service is done
          serviceConfig = {
            Type = "oneshot";
            # NOTE: to be able to see errors in your script do this
            # StandardOutput = "journal+console";
            # StandardError = "journal+console";
          };
          # This service is required for boot to succeed
          requiredBy = ["initrd.target"];
          # Should complete before any file systems are mounted
          before = ["sysroot.mount"];

          # Wait until the root device is available
          # If you're altering a different device, specify its device unit explicitly.
          # see: systemd-escape(1)
          requires = ["initrd-root-device.target"];
          after = [
            "initrd-root-device.target"
            # Allow hibernation to resume before trying to alter any data
            "local-fs-pre.target"
          ];

          # The body of the script. Make your changes to data here
          script = ''
            mkdir /btrfs_tmp
            mount /dev/root_vg/root /btrfs_tmp
            if [[ -e /btrfs_tmp/root ]]; then
                mkdir -p /btrfs_tmp/old_roots
                timestamp=$(date --date="@$(stat -c %Y /btrfs_tmp/root)" "+%Y-%m-%-d_%H:%M:%S")
                mv /btrfs_tmp/root "/btrfs_tmp/old_roots/$timestamp"
            fi

            delete_subvolume_recursively() {
                IFS=$'\n'
                for i in $(btrfs subvolume list -o "$1" | cut -f 9- -d ' '); do
                    delete_subvolume_recursively "/btrfs_tmp/$i"
                done
                btrfs subvolume delete "$1"
            }

            for i in $(find /btrfs_tmp/old_roots/ -maxdepth 1 -mtime +30); do
                delete_subvolume_recursively "$i"
            done

            btrfs subvolume create /btrfs_tmp/root
            umount /btrfs_tmp
          '';
        };
        extraBin = {
          # "mkfs.ext4" = "${pkgs.e2fsprogs}/bin/mkfs.ext4";
          "mkdir" = "${pkgs.coreutils}/bin/mkdir";
          "date" = "${pkgs.coreutils}/bin/date";
          "stat" = "${pkgs.coreutils}/bin/stat";
          "mv" = "${pkgs.coreutils}/bin/mv";
          "find" = "${pkgs.findutils}/bin/find";
          "btrfs" = "${pkgs.btrfs-progs}/bin/btrfs";
          # mount & umount already exist
        }; # NOTE: path = [...]; doesnt work for initrd, use full paths in your script or extraBin
      };