build.gradle

buildscript {
    repositories {
        jcenter()
        maven { url "https://plugins.gradle.org/m2/" }
    }
    dependencies {
        classpath "net.ltgt.gradle:gradle-apt-plugin:$APT_PLUGIN_VERSION"
        classpath "com.jfrog.bintray.gradle:gradle-bintray-plugin:$BINTRAY_PLUGIN_VERSION"
    }
}

// Populate deployment credentials in an environment-aware fashion.
//
// * Local development:
//      Stored in local.properties file on the machine
// * CI Server:
//      Stored in environment variables before launch
Properties properties = new Properties()

def credentialsFile = new File(project.rootDir, "local.properties")
if (credentialsFile.exists()) {
    credentialsFile.withReader { properties.load(it) }
}

// @formatter:off
def bintrayUser     = properties.getProperty("BINTRAY_USER",    System.getenv("bintrayUser"))
def bintrayKey      = properties.getProperty("BINTRAY_KEY",     System.getenv("bintrayKey"))
def sonatypeUser    = properties.getProperty("SONATYPE_USER",   System.getenv("sonatypeUser"))
def sonatypePass    = properties.getProperty("SONATYPE_PASS",   System.getenv("sonatypePass"))
// @formatter:on

allprojects {
    repositories {
        jcenter()
    }

    // Store deployment credentials
    ext.bintrayUser = bintrayUser
    ext.bintrayKey = bintrayKey
    ext.sonatypeUser = sonatypeUser
    ext.sonatypePass = sonatypePass
}