feat(elasticmq): init

Author: shunueda

doc/elasticmq.md

@@ -0,0 +1,7 @@
+# ElasticMQ
+
+[ElasticMQ](https://github.com/softwaremill/elasticmq) is a message queue system, offering an actor-based Scala and an SQS-compatible REST (query) interface.
+
+## Usage example
+
+<https://github.com/juspay/services-flake/blob/main/nix/services/elasticmq_test.nix>

doc/services.md

@@ -8,6 +8,7 @@ short-title: Services
 - [[azurite]]#
 - [[cassandra]]#
 - [[clickhouse]]#
+- [[elasticmq]]#
 - [[elasticsearch]]#
 - [[grafana]]#
   - [[tempo]]

nix/services/default.nix

@@ -6,6 +6,7 @@ in
     ./apache-kafka.nix
     ./azurite.nix
     ./clickhouse
+    ./elasticmq.nix
     ./elasticsearch.nix
     ./mongodb.nix
     ./mysql

nix/services/elasticmq.nix

@@ -0,0 +1,137 @@
+{ config, pkgs, lib, name, ... }:
+
+{
+  options = {
+    package = lib.mkPackageOption pkgs "elasticmq-server-bin" { };
+
+    nodeAddress = {
+      protocol = lib.mkOption {
+        type = lib.types.str;
+        default = "http";
+      };
+      host = lib.mkOption {
+        type = lib.types.str;
+        default = "localhost";
+      };
+      port = lib.mkOption {
+        type = lib.types.port;
+        default = 9324;
+      };
+      contextPath = lib.mkOption {
+        type = lib.types.str;
+        default = "";
+      };
+    };
+
+    restSqs = lib.mkOption {
+      type = lib.types.submodule {
+        options = {
+          enabled = lib.mkOption {
+            type = lib.types.bool;
+            default = true;
+          };
+          bindPort = lib.mkOption {
+            type = lib.types.port;
+            default = 9324;
+          };
+          bindHost = lib.mkOption {
+            type = lib.types.str;
+            default = "0.0.0.0";
+          };
+        };
+      };
+      default = { };
+    };
+
+    restStats = lib.mkOption {
+      type = lib.types.submodule {
+        options = {
+          enabled = lib.mkOption {
+            type = lib.types.bool;
+            default = true;
+          };
+          bindPort = lib.mkOption {
+            type = lib.types.port;
+            default = 9325;
+          };
+          bindHost = lib.mkOption {
+            type = lib.types.str;
+            default = "0.0.0.0";
+          };
+        };
+      };
+      default = { };
+    };
+
+    generateNodeAddress = lib.mkOption {
+      type = lib.types.bool;
+      default = false;
+    };
+
+    extraOptions = lib.mkOption {
+      type = lib.types.lines;
+      default = "";
+      description = "Additional raw HOCON options to append.";
+    };
+  };
+
+  config.outputs.settings.processes."${name}" =
+    let
+      confFile = pkgs.writeText "elasticmq.conf" ''
+        node-address {
+          protocol = ${config.nodeAddress.protocol}
+          host = ${config.nodeAddress.host}
+          port = ${toString config.nodeAddress.port}
+          context-path = "${config.nodeAddress.contextPath}"
+        }
+
+        rest-sqs {
+          enabled = ${lib.boolToString config.restSqs.enabled}
+          bind-port = ${toString config.restSqs.bindPort}
+          bind-hostname = "${config.restSqs.bindHost}"
+        }
+
+        rest-stats {
+          enabled = ${lib.boolToString config.restStats.enabled}
+          bind-port = ${toString config.restStats.bindPort}
+          bind-hostname = "${config.restStats.bindHost}"
+        }
+
+        generate-node-address = ${lib.boolToString config.generateNodeAddress}
+
+        ${config.extraOptions}
+      '';
+
+      startCommand = pkgs.writeShellApplication {
+        name = "start-elasticmq";
+        runtimeInputs = [ config.package ];
+        runtimeEnv = {
+          JAVA_TOOL_OPTIONS = "-Dconfig.file=${confFile}";
+        };
+        text = ''
+          exec elasticmq-server
+        '';
+      };
+    in
+    {
+      command = startCommand;
+
+      readiness_probe = lib.optionalAttrs config.restSqs.enabled {
+        http_get = {
+          host = config.restSqs.bindHost;
+          port = config.restSqs.bindPort;
+          path = "/health";
+        };
+        initial_delay_seconds = 2;
+        period_seconds = 10;
+        timeout_seconds = 4;
+        success_threshold = 1;
+        failure_threshold = 5;
+      };
+      # https://github.com/F1bonacc1/process-compose#-auto-restart-if-not-healthy
+      availability = {
+        restart = "on_failure";
+        max_restarts = 5;
+      };
+    };
+}

nix/services/elasticmq_test.nix

@@ -0,0 +1,29 @@
+{ pkgs
+, config
+, ...
+}: {
+  services.elasticmq."elasticmq1" = {
+    enable = true;
+  };
+
+  settings.processes.test =
+    let
+      inherit (config.services.elasticmq."elasticmq1".restSqs) bindHost bindPort;
+    in
+    {
+      command = pkgs.writeShellApplication {
+        name = "dynamodb-test";
+        runtimeInputs = with pkgs; [ awscli2 jq ];
+        runtimeEnv = {
+          AWS_ACCESS_KEY_ID = "fake";
+          AWS_SECRET_ACCESS_KEY = "fake";
+          AWS_DEFAULT_REGION = "us-east-1";
+        };
+        text = ''
+          aws sqs list-queues --endpoint-url "http://${bindHost}:${toString bindPort}" \
+          | jq '.QueueUrls'
+        '';
+      };
+      depends_on."elasticmq1".condition = "process_healthy";
+    };
+}

test/flake.nix

@@ -44,6 +44,7 @@
             "${inputs.services-flake}/nix/services/azurite_test.nix"
             "${inputs.services-flake}/nix/services/cassandra_test.nix"
             "${inputs.services-flake}/nix/services/clickhouse/clickhouse_test.nix"
+            "${inputs.services-flake}/nix/services/elasticmq_test.nix"
             "${inputs.services-flake}/nix/services/grafana_test.nix"
             "${inputs.services-flake}/nix/services/memcached_test.nix"
             "${inputs.services-flake}/nix/services/minio_test.nix"