lawnch-plugins/CMakeLists.txt at main · hoppxi/lawnch-plugins · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
cmake_minimum_required(VERSION 3.17)
project(lawnch-plugin-api LANGUAGES CXX)

add_library(LawnchPluginApi INTERFACE)
add_library(Lawnch::PluginApi ALIAS LawnchPluginApi)

include(GNUInstallDirs)

target_include_directories(LawnchPluginApi INTERFACE
  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/lawnch>
  $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/lawnch>
)

install(TARGETS LawnchPluginApi
  EXPORT LawnchPluginApiTargets
  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)

install(DIRECTORY include/lawnch
  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)

install(EXPORT LawnchPluginApiTargets
  FILE LawnchPluginApiTargets.cmake
  NAMESPACE Lawnch::
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/LawnchPluginApi
)

include(CMakePackageConfigHelpers)
write_basic_package_version_file(
  "LawnchPluginApiConfigVersion.cmake"
  VERSION 0.2.0-alpha
  COMPATIBILITY SameMajorVersion
)

configure_package_config_file(
  "${CMAKE_CURRENT_LIST_DIR}/cmake/LawnchPluginApiConfig.cmake.in"
  "${CMAKE_CURRENT_BINARY_DIR}/LawnchPluginApiConfig.cmake"
  INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/LawnchPluginApi
)

install(FILES
  "${CMAKE_CURRENT_BINARY_DIR}/LawnchPluginApiConfig.cmake"
  "${CMAKE_CURRENT_BINARY_DIR}/LawnchPluginApiConfigVersion.cmake"
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/LawnchPluginApi
)