Pastel3d/gpio.asm at master · fstasel/Pastel3d · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
//--------------------------------------------------
// SUBROUTINES - GPIO
//--------------------------------------------------

.pc = *		"GPIO Module"

//--------------------------------------------------

func_initIO:
	lda #0
	sta BORDER_REG
	sta BG1_REG
	lda #1
	sta IO_STRCOLOR
	:sto16(print_addr, clrscn)
	jsr func_prints
	:sto16(print_addr, set2)
	jsr func_prints
	:sto16(print_addr, text_title)
	jsr func_prints

	// Start SID random number generator
	lda #$FF
	sta $D40E
	sta $D40F
	lda #$80
	sta $D412
	rts

//--------------------------------------------------

func_prints:
	pha
	tya
	pha
	lda print_addr
	ldy print_addr + 1
	jsr IO_PRINTSTR
	pla
	tay
	pla
	rts

//--------------------------------------------------

func_printu:
	pha
	txa
	pha
	tya
	pha
	ldy #0
!loop:	tya pha
	:sto16(tmp, 10)
	:unsigned_div16(print_val, tmp, tmp2, tmp3)
	:mov16(tmp2, print_val)
	:add8(tmp3, zero, tmp3)
	pla tay iny
	lda tmp3 pha
	:cmpz16(print_val)
	beq !over+
	jmp !loop-
!over:	lda #0 sta tmp3 + 1
	:sto16(print_addr, tmp3)
!loop:	pla sta tmp3
	tya pha
	jsr func_prints
	pla tay dey
	bne !loop-
	pla
	tay
	pla
	tax
	pla
	rts

//--------------------------------------------------

func_printd:
	pha
	bit print_val + 1
	bpl !else+
	:sto16(print_addr, minus)
	jsr func_prints
	:neg16(print_val)
	jmp !skip+
!else:	:sto16(print_addr, space)
	jsr func_prints
!skip:	jsr func_printu
	pla
	rts

//--------------------------------------------------

func_printlnd:
	jsr func_printd
	:sto16(print_addr, cr)
	jsr func_prints
	rts

//--------------------------------------------------

func_printf:
	bit print_val + 1
	bpl !skip+
	:neg8(print_val)
!skip:	lda #0
	sta print_val + 1
	:sto16(print_addr, tmp)
!loop:	:sto16(tmp, 10)
	:mul16(print_val, tmp, tmp2)
	:mov16(tmp2, print_val)
	:add8(print_val + 1, zero, tmp)
	jsr func_prints
	lda #0
	sta print_val + 1
	lda print_val
	bne !loop-
	rts

//--------------------------------------------------

func_printfp:
	:mov32(print_val, FP1)
	jsr fix
	lda m1
	sta print_val + 1
	sta tmp2
	lda m1 + 1
	sta print_val
	lda m1 + 2
	sta tmp
	jsr func_printd
	:sto16(print_addr, dot)
	jsr func_prints
	lda tmp
	sta print_val
	lda tmp2
	sta print_val + 1
	jsr func_printf
	rts

//--------------------------------------------------

func_printlnfp:
	jsr func_printfp
	:sto16(print_addr, cr)
	jsr func_prints
	rts

//--------------------------------------------------

func_paint:
	pha tya pha lda r0 pha lda r1 pha
	lda paint_y
	sta r0
	lda #0
	sta r0 + 1
	:shl16(r0)
	:shl16(r0)
	:shl16(r0)
	:mov16(r0, r1)
	:shl16(r0)
	:shl16(r0)
	:add16(r1, r0, r1)
	ldy paint_x
	:sto16(r0, COL_SEGMENT)
	:add16(r0, r1, r0)
	lda paint_col
	sta (r0),y
	:sto16(r0, CHR_SEGMENT)
	:add16(r0, r1, r0)
	lda #$A0
	sta (r0),y
	pla sta r1 pla sta r0 pla tay pla
	rts

//--------------------------------------------------
// DATA
//--------------------------------------------------
set1:		.byte $8e, 0
set2:		.byte $0e, 0
clrscn:		.byte $93, 0
gohome:		.byte $13, 0
cr:		.byte 13, 0
minus:		.text "-" .byte 0
space:		.text " " .byte 0
dot:		.text "." .byte 0
zero:		.text "0" .byte 0

//--------------------------------------------------
// SUBROUTINES' VARIABLES
//--------------------------------------------------
print_addr:	.word 0
print_val:	.dword 0
tmp:		.word 0
tmp2:		.word 0
tmp3:		.word 0
paint_x:	.byte 0
paint_y:	.byte 0
paint_col:	.byte 0