Pull optimization into shift_zone_for_iso_days_utc

Author: reisub

lib/elixir/lib/calendar/datetime.ex

@@ -720,6 +720,9 @@ defmodule DateTime do
   Other time zone databases can be passed as argument or set globally.
   See the "Time zone database" section in the module docs.
 
+  Shifting to the `"Etc/UTC"` time zone always succeeds without
+  consulting the `time_zone_database`.
+
   ## Examples
 
       iex> {:ok, pacific_datetime} = DateTime.shift_zone(~U[2018-07-16 10:00:00Z], "America/Los_Angeles", FakeTimeZoneDatabase)
@@ -753,6 +756,28 @@ defmodule DateTime do
     |> shift_zone_for_iso_days_utc(calendar, precision, time_zone, time_zone_database)
   end
 
+  defp shift_zone_for_iso_days_utc(iso_days_utc, calendar, precision, "Etc/UTC", _time_zone_db) do
+    {year, month, day, hour, minute, second, {microsecond, _}} =
+      calendar.naive_datetime_from_iso_days(iso_days_utc)
+
+    datetime = %DateTime{
+      calendar: calendar,
+      year: year,
+      month: month,
+      day: day,
+      hour: hour,
+      minute: minute,
+      second: second,
+      microsecond: {microsecond, precision},
+      std_offset: 0,
+      utc_offset: 0,
+      zone_abbr: "UTC",
+      time_zone: "Etc/UTC"
+    }
+
+    {:ok, datetime}
+  end
+
   defp shift_zone_for_iso_days_utc(iso_days_utc, calendar, precision, time_zone, time_zone_db) do
     case time_zone_db.time_zone_period_from_utc_iso_days(iso_days_utc, time_zone) do
       {:ok, %{std_offset: std_offset, utc_offset: utc_offset, zone_abbr: zone_abbr}} ->
@@ -1708,44 +1733,6 @@ defmodule DateTime do
     add(datetime, amount_to_add * 60, :second, time_zone_database)
   end
 
-  def add(
-        %{calendar: calendar, time_zone: "Etc/UTC"} = datetime,
-        amount_to_add,
-        unit,
-        _time_zone_database
-      )
-      when is_integer(amount_to_add) do
-    %{microsecond: {_, precision}} = datetime
-
-    if not is_integer(unit) and unit not in ~w(second millisecond microsecond nanosecond)a do
-      raise ArgumentError,
-            "unsupported time unit. Expected :day, :hour, :minute, :second, :millisecond, :microsecond, :nanosecond, or a positive integer, got #{inspect(unit)}"
-    end
-
-    precision = max(Calendar.ISO.time_unit_to_precision(unit), precision)
-
-    {year, month, day, hour, minute, second, {microsecond, _}} =
-      datetime
-      |> to_iso_days()
-      |> Calendar.ISO.shift_time_unit(amount_to_add, unit)
-      |> calendar.naive_datetime_from_iso_days()
-
-    %DateTime{
-      calendar: calendar,
-      year: year,
-      month: month,
-      day: day,
-      hour: hour,
-      minute: minute,
-      second: second,
-      microsecond: {microsecond, precision},
-      time_zone: "Etc/UTC",
-      zone_abbr: "UTC",
-      utc_offset: 0,
-      std_offset: 0
-    }
-  end
-
   def add(%{calendar: calendar} = datetime, amount_to_add, unit, time_zone_database)
       when is_integer(amount_to_add) do
     %{
@@ -1785,6 +1772,9 @@ defmodule DateTime do
 
   Allowed units are: `:year`, `:month`, `:week`, `:day`, `:hour`, `:minute`, `:second`, `:microsecond`.
 
+  If the datetime is in the `"Etc/UTC"` time zone, this function
+  always succeeds without consulting the `time_zone_database`.
+
   This operation is equivalent to shifting the datetime wall clock
   (in other words, the value as someone in that timezone would see
   on their watch), then applying the time zone offset to convert it
@@ -1853,44 +1843,6 @@ defmodule DateTime do
   @spec shift(Calendar.datetime(), Duration.duration(), Calendar.time_zone_database()) :: t
   def shift(datetime, duration, time_zone_database \\ Calendar.get_time_zone_database())
 
-  def shift(%{calendar: calendar, time_zone: "Etc/UTC"} = datetime, duration, _time_zone_database) do
-    %{
-      year: year,
-      month: month,
-      day: day,
-      hour: hour,
-      minute: minute,
-      second: second,
-      microsecond: microsecond
-    } = datetime
-
-    {year, month, day, hour, minute, second, microsecond} =
-      calendar.shift_naive_datetime(
-        year,
-        month,
-        day,
-        hour,
-        minute,
-        second,
-        microsecond,
-        __duration__!(duration)
-      )
-
-    %DateTime{
-      year: year,
-      month: month,
-      day: day,
-      hour: hour,
-      minute: minute,
-      second: second,
-      microsecond: microsecond,
-      time_zone: "Etc/UTC",
-      zone_abbr: "UTC",
-      std_offset: 0,
-      utc_offset: 0
-    }
-  end
-
   def shift(%{calendar: calendar} = datetime, duration, time_zone_database) do
     %{
       year: year,

lib/elixir/test/elixir/calendar/datetime_test.exs

@@ -961,6 +961,18 @@ defmodule DateTimeTest do
   end
 
   describe "shift_zone" do
+    test "to Etc/UTC does not consult the time zone database" do
+      dt =
+        DateTime.from_naive!(
+          ~N[2018-07-16 12:00:00.123],
+          "Europe/Copenhagen",
+          FakeTimeZoneDatabase
+        )
+
+      assert DateTime.shift_zone(dt, "Etc/UTC", EmptyTimeZoneDatabase) ==
+               {:ok, ~U[2018-07-16 10:00:00.123Z]}
+    end
+
     test "with compatible calendar" do
       holocene_ndt = %NaiveDateTime{
         calendar: Calendar.Holocene,
@@ -1195,4 +1207,12 @@ defmodule DateTimeTest do
                  "unknown unit :months. Expected :year, :month, :week, :day, :hour, :minute, :second, :microsecond",
                  fn -> DateTime.shift(~U[2012-01-01 00:00:00Z], months: 12) end
   end
+
+  test "shift/3 with Etc/UTC datetime does not consult the time zone database" do
+    assert DateTime.shift(~U[2000-01-01 00:00:00Z], [month: 1], EmptyTimeZoneDatabase) ==
+             ~U[2000-02-01 00:00:00Z]
+
+    assert DateTime.shift(~U[2000-01-01 00:00:00.123Z], [hour: -1], EmptyTimeZoneDatabase) ==
+             ~U[1999-12-31 23:00:00.123Z]
+  end
 end