numbsql/flake.nix at main · cpcloud/numbsql · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
{
  description = "Numba UD(A)Fs for SQLite";

  inputs = {
    flake-compat = {
      url = "github:edolstra/flake-compat";
      flake = false;
    };

    flake-utils.url = "github:numtide/flake-utils";

    gitignore = {
      url = "github:hercules-ci/gitignore.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable-small";

    pyproject-nix = {
      url = "github:nix-community/pyproject.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    uv2nix = {
      url = "github:adisbladis/uv2nix";
      inputs = {
        pyproject-nix.follows = "pyproject-nix";
        nixpkgs.follows = "nixpkgs";
      };
    };

    pyproject-build-systems = {
      url = "github:pyproject-nix/build-system-pkgs";
      inputs = {
        pyproject-nix.follows = "pyproject-nix";
        uv2nix.follows = "uv2nix";
        nixpkgs.follows = "nixpkgs";
      };
    };

    git-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    { self
    , flake-utils
    , gitignore
    , nixpkgs
    , uv2nix
    , git-hooks
    , pyproject-nix
    , pyproject-build-systems
    , ...
    }:
    {
      overlays.default = nixpkgs.lib.composeManyExtensions [
        gitignore.overlay
        (import ./nix/overlay.nix { inherit uv2nix pyproject-nix pyproject-build-systems; })
      ];
    }
    // (flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ self.overlays.default ];
        };
        inherit (pkgs) lib;
      in
      rec {
        packages.numbsql310 = pkgs.numbsql310;
        packages.numbsql311 = pkgs.numbsql311;
        packages.numbsql312 = pkgs.numbsql312;
        packages.numbsql313 = pkgs.numbsql313;

        packages.numbsql = pkgs.numbsql313;

        defaultPackage = packages.numbsql;

        checks = {
          pre-commit = git-hooks.lib.${system}.run {
            src = ./.;
            hooks = {
              ruff.enable = true;
              deadnix.enable = true;
              nixpkgs-fmt.enable = true;
              shellcheck.enable = true;
              statix.enable = true;
              mypy.enable = true;
              taplo.enable = true;

              ruff-format = {
                enable = true;
                types = [ "python" ];
                entry = "${pkgs.ruff}/bin/ruff format";
              };

              shfmt = {
                enable = true;
                files = "\\.sh$";
                entry = lib.mkForce "shfmt -i 2 -sr -s";
              };

              prettier = {
                enable = true;
                types_or = [
                  "json"
                  "yaml"
                ];
              };
            };
          };
        };

        devShell =
          let
            sqlite3LdLibraryPath = lib.makeLibraryPath [ pkgs.sqlite ];
            env = pkgs.numbsqlDevEnv313;
          in
          pkgs.mkShell
            {
              inherit (env) name;
              nativeBuildInputs = with pkgs; [
                env
                uv
                # useful for testing sqlite things with a sane CLI, i.e., with
                # readline
                sqlite-interactive
              ];
              inherit (self.checks.${system}.pre-commit) shellHook;
              NUMBA_CAPTURED_ERRORS = "new_style";
              LD_LIBRARY_PATH = sqlite3LdLibraryPath;
            }
          // pkgs.lib.optionalAttrs pkgs.stdenv.isDarwin {
            DYLD_LIBRARY_PATH = sqlite3LdLibraryPath;
            NIXPKGS_ALLOW_UNFREE = "1";
            JUPYTER_PLATFORM_DIRS = "1";
          };
      }
    ));
}