nmrs/flake.nix at master · cachebag/nmrs · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
{
  description = "nmrs development flake";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
    naersk.url = "github:nix-community/naersk/master";
    flake-utils.url = "github:numtide/flake-utils";

    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    naersk,
    rust-overlay,
  }:
    flake-utils.lib.eachDefaultSystem (
      system: let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [(import rust-overlay)];
        };
        toolchain = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;

        naersk-package = pkgs.callPackage naersk {
          cargo = toolchain;
          rustc = toolchain;
          clippy = toolchain;
        };
      in {
        devShell = with pkgs;
          mkShell {
            buildInputs = [
              cargo
              cargo-info
              rustc
              rustfmt
              clippy
              rust-analyzer
              just

              eza
              fd
              fzf
              bat

              pkg-config
              libxkbcommon
              glib
              gobject-introspection
              gtk4
              libadwaita
            ];
            RUST_SRC_PATH = "${pkgs.rust.packages.stable.rustPlatform.rustLibSrc}";

            shellHook = ''
              alias ls=eza
              alias find=fd
            '';
          };

        packages.default = naersk-package.buildPackage {
          name = "nmrs";
          version = self.shortRev or self.dirtyShortRev;
          src = ./.;

          buildInputs = with pkgs; [
            pkg-config
            wrapGAppsHook4
            libxkbcommon
            glib
          ];

          postInstall = ''
            install -D nmrs.desktop -t $out/share/applications
          '';

          meta.mainProgram = "nmrs-gui";
        };
      }
    );
}