build.gradle

plugins {
    id "jacoco"
    alias(libs.plugins.spotless)
    alias(libs.plugins.publish)
}

repositories {
    mavenCentral()
}

subprojects {
    apply from: rootProject.file('common.gradle')
}

task mergedJavadoc(type: Javadoc, description: 'Creates Javadoc from all the projects.') {
    title = 'All modules'
    destinationDir = new File(project.buildDir, 'merged-javadoc')

    // Note: The closures below are executed lazily.
    source {
        subprojects*.sourceSets*.main*.allSource
    }
    classpath.from {
        subprojects*.configurations*.compile*.copyRecursive({ !(it instanceof ProjectDependency) })*.resolve()
    }
}

spotless {
    java {
        target 'src/*/java/**/*.java'
        // note: you can use an empty string for all the imports you didn't specify explicitly, and '\\#` prefix for static imports
        importOrder('java', 'javax', 'org.openjdk.btrace', '', '\\#org.openjdk.btrace', '\\#')
        removeUnusedImports()

        googleJavaFormat()   // has its own section below

        formatAnnotations()  // fixes formatting of type annotations, see below

        licenseHeader '/* (C) $YEAR */' // or licenseHeaderFile
    }
}

// Nexus Publishing configuration for Maven Central release automation
// This enables the closeAndReleaseStagingRepositories task for automated releases
// Uses the new Central Portal URLs (OSSRH was sunset on June 30, 2025)
nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
            // Use Central Portal user token credentials (different from legacy OSSRH credentials)
            username = findProperty("sonatype.user")
                    ?: findProperty("sonatype.username")
                    ?: System.getenv("SONATYPE_USER")
                    ?: System.getenv("SONATYPE_USERNAME")
            password = findProperty("sonatype.password")
                    ?: System.getenv("SONATYPE_PASSWORD")
        }
    }
}

def sonatypeUsername = findProperty("sonatype.user")
        ?: findProperty("sonatype.username")
        ?: System.getenv("SONATYPE_USER")
        ?: System.getenv("SONATYPE_USERNAME")
def sonatypePassword = findProperty("sonatype.password")
        ?: System.getenv("SONATYPE_PASSWORD")
def hasSonatypeCredentials =
        sonatypeUsername != null && !sonatypeUsername.toString().trim().isEmpty()
                && sonatypePassword != null
                && !sonatypePassword.toString().trim().isEmpty()

if (!hasSonatypeCredentials || project.version.endsWith("-SNAPSHOT")) {
    logger.lifecycle("Sonatype credentials not provided or running with snapshot; skipping Nexus staging initialization and release tasks.")
    def skipTheseTasks = [
        "initializeSonatypeStagingRepository",
        "publishToSonatype",
        "closeSonatypeStagingRepository",
        "dropSonatypeStagingRepository",
        "releaseSonatypeStagingRepository",
    ]
    tasks.matching { skipTheseTasks.contains(it.name) }.configureEach {
        enabled = false
    }
}