arkanjo/CMakeLists.txt at main · arkanjo-tool/arkanjo · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
cmake_minimum_required(VERSION 3.19)

execute_process(
    COMMAND git describe --tags --abbrev=0
    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
    OUTPUT_VARIABLE GIT_TAG
    OUTPUT_STRIP_TRAILING_WHITESPACE
)

string(REGEX REPLACE "^v" "" ARKANJO_PROJECT_VERSION "${GIT_TAG}")

if(NOT ARKANJO_PROJECT_VERSION)
    message(WARNING "ARKANJO_PROJECT_VERSION is empty")
endif()

project(arkanjo
    VERSION ${ARKANJO_PROJECT_VERSION}
    LANGUAGES C CXX
)

option(ENABLE_WARNINGS "Enable compiler warnings" OFF)
option(ENABLE_TESTS "Build tests" ON)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

set(CMAKE_C_STANDARD 11)
set(CMAKE_C_STANDARD_REQUIRED ON)
set(CMAKE_C_EXTENSIONS ON)

if(NOT CMAKE_CONFIGURATION_TYPES AND NOT CMAKE_BUILD_TYPE)
    set(CMAKE_BUILD_TYPE Release CACHE STRING "" FORCE)
endif()

include(GNUInstallDirs)

set(THIRD_PARTY_BUILD_DIR "${CMAKE_BINARY_DIR}/third-party")

include(cmake/TreeSitter.cmake)
include(cmake/Libgit2.cmake)
include(cmake/CompilerOptions.cmake)
include(cmake/Targets.cmake)
include(cmake/Documentation.cmake)

if(ENABLE_TESTS)
    enable_testing()

    add_executable(arkanjo-test
        tests/e2e/test.cpp
    )
    target_link_libraries(arkanjo-test PRIVATE
        core_base core_utils core_commands core_cli core_git project_options
    )

    add_test(NAME run_tests COMMAND arkanjo-test)
    set_tests_properties(run_tests PROPERTIES
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
    )
endif()

install(TARGETS arkanjo arkanjo-preprocessor
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)
#install(DIRECTORY include/
#    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
#)
install(DIRECTORY third-party/
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/arkanjo/third-party
)

include(cmake/Formatter.cmake)

message(STATUS "Build type: ${CMAKE_BUILD_TYPE}")
message(STATUS "System: ${CMAKE_SYSTEM_NAME}")
message(STATUS "Compiler: ${CMAKE_CXX_COMPILER_ID}")