Dynamically adjustable voltage driven from timer

[Phat-Dad-Racing]

Just sharing something that I found useful. TBH, not using a whole lot of this core's functions, but I thought I'd share anyway.

I wanted to generate a controlled PWM signal with adjustable voltage output. I've experimented with a few options, but remembered that the DB has an internal opamp that is also event system-enabled. So, with very minimal code, attached TCA overflow and CMP events to enable/disable on the opamp which seems to respond a bit faster than the DAC. Feed the voltage from the DAC into the opamp configured as voltage follower and it seems to work fine for my needs (relatively low frequencies: 50Hz ~ 1500Hz). The opamp output is only slightly delayed and I think has an acceptable rise time.

As I said, mostly FYI - but if people know smarter ways, I'm all ears.

In this picture, CH1 is tracking the digital pin connected directly to TCA0, CH2 is tracking the opamp output.

Also, I do not understand settling time...

uint16_t  dacValue;
void setup() {

  takeOverTCA0();
   
  setupDAC0();
  setupOpAmp();
  setupTCA0();
  setupEvents();
  dacValue = 512;

  setDAC0_output(dacValue); // Up to a 10-bit value
  
}

void loop() {
  
  dacValue = dacValue + 10;
  if(dacValue > 1023){
     dacValue = 150;
  }
  setDAC0_output(dacValue);
  delay(30);
}


void setupTCA0()
{

  // Set up TCA0 to run in single PWM mode
  
  // Set pin to output
  pinMode(PIN_PC0, OUTPUT);
  // Route output to port C - WO0 appears on PC0
  PORTMUX.TCAROUTEA |= PORTMUX_TCA01_bm;

  // This should be 1500 clocks wide
  TCA0.SINGLE.CMP0 = 0x5dc; /* Compare Register 0: 0x5dc */

  
  TCA0.SINGLE.CTRLB = 0 << TCA_SINGLE_ALUPD_bp            /* Auto Lock Update: disabled */
                      | 1 << TCA_SINGLE_CMP0EN_bp         /* Compare 0 Enable: enabled */
                      | 0 << TCA_SINGLE_CMP1EN_bp         /* Compare 1 Enable: disabled */
                      | 0 << TCA_SINGLE_CMP2EN_bp         /* Compare 2 Enable: disabled */
                      | TCA_SINGLE_WGMODE_SINGLESLOPE_gc; /*  */

  TCA0.SINGLE.CTRLC = 1 << TCA_SINGLE_CMP0OV_bp    /* Compare 0 Waveform Output Value: enabled */
                      | 0 << TCA_SINGLE_CMP1OV_bp  /* Compare 1 Waveform Output Value: disabled */
                      | 0 << TCA_SINGLE_CMP2OV_bp; /* Compare 2 Waveform Output Value: disabled */

  
 TCA0.SINGLE.PER = 0x4e20; /* Period: 0x4e20 */

  TCA0.SINGLE.CTRLA = TCA_SINGLE_CLKSEL_DIV16_gc     /* System Clock / 16 */
                      | 1 << TCA_SINGLE_ENABLE_bp    /* Module Enable: enabled */
                      | 0 << TCA_SINGLE_RUNSTDBY_bp; /* RUN STANDBY: disabled */
}

void setupEvents()
{

  EVSYS.CHANNEL0 = EVSYS_CHANNEL0_TCA0_CMP0_LCMP0_gc; /* Timer/Counter A0 compare 0 / low byte timer compare 0 */

  EVSYS.CHANNEL1 = EVSYS_CHANNEL1_TCA0_OVF_LUNF_gc; /* Timer/Counter A0 overflow / low byte timer underflow */

  EVSYS.USEROPAMP0ENABLE = EVSYS_USER_CHANNEL1_gc; /* Connect user to event channel 1 */

  EVSYS.USEROPAMP0DISABLE = EVSYS_USER_CHANNEL0_gc; /* Connect user to event channel 0 */

}

void setupDAC0()
{

  DAC0.DATA = 0x0 << DAC_DATA_gp; /* DATA Register: 0x0 */

  DAC0.CTRLA = 1 << DAC_ENABLE_bp      /* DAC Enable: enabled */
               | 1 << DAC_OUTEN_bp     /* Output Buffer Enable: enabled */
               | 0 << DAC_RUNSTDBY_bp; /* Run in Standby Mode: disabled */

}

void setDAC0_output(uint16_t value)
{
  value     = value << DAC_DATA_gp;
  value     = value & 0xFFC0;
  DAC0.DATA = value;
}

void setupOpAmp()
{

  pinMode(PIN_PD2, OUTPUT);
  OPAMP.CTRLA = 1 << OPAMP_ENABLE_bp; /* OPAMP Peripheral Enable: enabled */
  
  OPAMP.TIMEBASE = 16 << OPAMP_TIMEBASE_gp;

  OPAMP.OP0SETTLE = 0x7f << OPAMP_SETTLE_gp; /* Setting: 0x7f */

  OPAMP.OP0CTRLA = 0 << OPAMP_ALWAYSON_bp             /* Always ON: disabled (?) */
                   | 1 << OPAMP_EVENTEN_bp            /* Event Enable: enabled */
                   | OPAMP_OP0CTRLA_OUTMODE_NORMAL_gc /* Output Driver in Normal Mode */
                   | 0 << OPAMP_RUNSTBY_bp;           /* Run is standby mode: disabled */


  OPAMP.OP0INMUX = OPAMP_OP0INMUX_MUXPOS_DAC_gc    /* DAC output */
                   | OPAMP_OP0INMUX_MUXNEG_OUT_gc; /* OPn output (unity gain) */

  
}