ComponentInitializer/config.gradle at master · RocketZLY/ComponentInitializer · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
ext {
    androidConfig = [
            compileVersion : 28,
            minVersion     : 15,
            targetVersion  : 28,
            releaseProguard: true,
            debugProguard  : true
    ]

    /**
     * 上传配置
     */
    publishConfig = [
            userOrg: 'zhuliyuan',//bintray.com用户名
            groupId: 'com.rocketzly',//jcenter上的路径
            desc   : '一个组件初始化辅助工具',//描述，自由填写
            website: 'https://github.com/RocketZLY/ComponentInitializer' // 网址，自由填写
    ]

    /**
     * 模块调试配置
     */
    debugConfig = [
            ComponentInitializerApi      : false,
            ComponentInitializerCommon   : false,
            ComponentInitializerProcessor: false
    ]

    libsVersion = [
            junit                        : '4.12',
            appcompat                    : '28.0.0',
            auto_service                 : '1.0-rc2',
            javapoet                     : '1.11.1',
            componentinitializer_api     : '1.0.2',
            componentinitializer_compiler: '1.0.1',
            componentinitializer_common  : '1.0.0'
    ]

    libs = [
            junit                        : "junit:junit:$libsVersion.junit",
            kotlin                       : "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version",
            appcompat_v7                 : "com.android.support:appcompat-v7:$libsVersion.appcompat",
            auto_service                 : "com.google.auto.service:auto-service:$libsVersion.auto_service",
            javapoet                     : "com.squareup:javapoet:$libsVersion.javapoet",
            componentinitializer_api     : debugConfig.ComponentInitializerApi ? project(':ComponentInitializerApi') : "com.rocketzly:componentinitializer-api:$libsVersion.componentinitializer_api",
            componentinitializer_common  : debugConfig.ComponentInitializerCommon ? project(':ComponentInitializerCommon') : "com.rocketzly:componentinitializer-common:$libsVersion.componentinitializer_common",
            componentinitializer_compiler: debugConfig.ComponentInitializerProcessor ? project(':ComponentInitializerProcessor') : "com.rocketzly:componentinitializer-compiler:$libsVersion.componentinitializer_compiler"
    ]

    /**
     * app模块依赖关系
     */
    appDependencies = [
            implementation: [
                    libs.kotlin,
                    project(':common'),
                    project(':moduleA'),
                    project(':moduleB'),
                    project(':moduleC')
            ]
    ]

    /**
     * common模块依赖关系
     */
    commonDependencies = [
            api: [
                    libs.appcompat_v7,
                    libs.componentinitializer_api
            ]
    ]

    /**
     * ComponentInitializerApi模块依赖关系
     */
    ComponentInitializerApiDependencies = [
            api: [
                    libs.componentinitializer_common
            ]
    ]

    /**
     * ComponentInitializerProcessor模块依赖关系
     */
    ComponentInitializerProcessorDependencies = [
            implementation: [
                    libs.auto_service,
                    libs.javapoet,
                    libs.componentinitializer_common
            ]
    ]

    /**
     * sampleModule 样例module依赖关系
     */
    sampleModuleDependencies = [
            implementation     : [
                    project(':common')
            ],
            annotationProcessor: [
                    libs.componentinitializer_compiler
            ]
    ]

    /**
     * 生成模块依赖关系
     */
    generateDependencies = { handler, moduleDependencies ->
        moduleDependencies.each { relation, libs ->
            libs.each {
                switch (relation) {
                    case "implementation":
                        handler.implementation it
                        break
                    case "api":
                        handler.api it
                        break
                    case "annotationProcessor":
                        handler.annotationProcessor it
                        break
                }
            }
        }
        //增加通用的junit
        handler.testImplementation libs.junit
    }

}