Issue with SPARQL Query Filtering by Polish Buyers - Getting Limited Results

[rkrol-dev]

I'm experiencing an issue with filtering procurement notices by buyer country using SPARQL queries. When filtering for Polish buyers (POL), I only get notices from European agencies like FRONTEX, but when filtering for German buyers (DEU) or Czech buyers (CZE), I get the expected diverse range of national contracting authorities.

`
PREFIX epo: http://data.europa.eu/a4g/ontology#
PREFIX dcterms: http://purl.org/dc/terms/
PREFIX xsd: http://www.w3.org/2001/XMLSchema#
PREFIX ns8: http://data.europa.eu/m8g/
PREFIX ns11: http://publications.europa.eu/resource/authority/country/
PREFIX ns17: http://www.w3.org/ns/adms#
PREFIX skos: http://www.w3.org/2004/02/skos/core#

SELECT DISTINCT
?publicationNumber
?publicationDate
?procedureTitle_pl
?buyerName
?buyerNationalId

WHERE {

FILTER (?publicationDate >= "2025-01-01"^^xsd:date &&
?publicationDate <= "2025-01-31"^^xsd:date)

GRAPH ?g {
?notice a epo:Notice ;
epo:hasNoticePublicationNumber ?publicationNumber ;
epo:hasPublicationDate ?publicationDate ;
epo:announcesRole [
a epo:Buyer ;
epo:playedBy ?buyerOrganization
] ;
epo:refersToProcedure ?procedure .

?buyerOrganization ns8:registeredAddress [
  epo:hasCountryCode ns11:POL  # For Poland
] .

}

?buyerOrganization epo:hasLegalName ?buyerName .

OPTIONAL {
?buyerOrganization epo:hasLegalIdentifier ?buyerLegalId .
?buyerLegalId skos:notation ?buyerNationalId .
}

OPTIONAL {
?procedure dcterms:title ?procedureTitle_pl .
FILTER(LANG(?procedureTitle_pl) = "pl")
}

}
ORDER BY DESC(?publicationDate) ?publicationNumber
LIMIT 1000
`

Results Comparison
For Poland (ns11:POL): Only returns notices from:

• European Border and Coast Guard Agency (FRONTEX)
• European Commission, DG COMM - Communication

For Germany (ns11:DEU): Returns diverse results from:

• Stadt Essen, vertreten durch die GVE Grundstücksverwaltung Stadt Essen GmbH
• Freistaat Thüringen vertreten durch das Thüringer Landesrechenzentrum
• Fördeklinikum Katharinen-Hospital gGmbH
• Stadt Herbrechtingen
• Stadt Wesel
• etc.

Evidence That Polish Notices Exist
Using the TED website search with filters shows that Polish contracting authorities published notices in January 2025:
https://ted.europa.eu/en/search/result?notice-type=can-standard%2Ccan-social%2Ccan-desg%2Ccan-tran&publication-date-from=20250101&publication-date-to=20250131&buyer-country=POL&search-scope=ALL
The web search returns numerous notices from Polish municipalities, hospitals, universities, and other national institutions.

Question
What am I doing wrong in my SPARQL query? Is there:

1. A different property/structure for Polish buyer addresses in the RDF data?
2. An issue with how Polish contracting authorities are modeled compared to other EU countries?
3. A delay in data ingestion for Polish notices?
4. A different country code or URI structure I should be using for Poland?

I've verified that:

1. The country code ns11:POL exists in the authority tables
2. The same query structure works perfectly for other countries
3. The time filter is correct
4. Polish notices definitely exist in TED during this period

Any guidance on how to properly filter for Polish buyers would be greatly appreciated!

Additional Information

• SPARQL endpoint: https://publications.europa.eu/webapi/rdf/sparql
• Testing period: January 2025
• Expected behavior: Similar diverse results as seen for Germany/Czech Republic
• Actual behavior: Only European agency results

Thank you for your help!

[Anoop-Variyan]

Though the question is a few months old, here is a possible answer if it still helps and also for future reference.
The sample notice (https://ted.europa.eu/en/notice/-/detail/00070358-2025) mentioned in the question is a Result notice. For Result notices, announcesRole of Buyer type is not available. We can check the available relationships using the inspect option in https://data.ted.europa.eu/.
By replacing epo:announcesRole in the line epo:announcesRole [a epo:Buyer ; epo:playedBy ?buyerOrganization ] ; with epo:refersToRole, it fetches the sample notice too.