Simple query to filter after a cpv category.

[leobroom]

Hey,
I am new to the topic of Sparql and ePO and i am looking for a simple query to filter competition notices after main cpv categories. (for example cpv=71200000 ) and I can´t figure a way out. This is right now what I have. Does someone has an Idea how to solve the issue?
I am grateful for every comment/ feedback.
Thank you,
Leon

`PREFIX dc: http://purl.org/dc/elements/1.1/
PREFIX epo: http://data.europa.eu/a4g/ontology#
PREFIX cccev: http://data.europa.eu/m8g/
PREFIX org: http://www.w3.org/ns/org#
PREFIX xsd: http://www.w3.org/2001/XMLSchema#
PREFIX skos: http://www.w3.org/2004/02/skos/core#

SELECT DISTINCT ?publicationNumber ?legalName ?procedureType ?country
WHERE {
FILTER (?publicationDate = "2024-11-04"^^xsd:date)
FILTER (?formType = http://publications.europa.eu/resource/authority/form-type/competition)

GRAPH ?g {
    ?notice
        epo:hasPublicationDate ?publicationDate ;
        epo:refersToProcedure [
            epo:hasProcedureType ?procedureTypeUri ;
            a epo:Procedure
        ] ;
        epo:hasNoticePublicationNumber ?publicationNumber ;
        epo:hasFormType ?formType ;
        epo:announcesRole [
            a epo:Buyer ;
            epo:playedBy [
                epo:hasLegalName ?legalName ;
                cccev:registeredAddress [
                    epo:hasCountryCode ?countryUri
                ]
            ]
        ] ;
        epo:hasProcurementObject ?procurementObject .

    ?procurementObject epo:hasPurpose ?purpose .
    ?purpose epo:hasMainClassification ?mainClassification .
    
    FILTER(STRSTARTS(STR(?mainClassification), "http://data.europa.eu/cpv/cpv/71200000"))
}

?procedureTypeUri a skos:Concept ;
    skos:prefLabel ?procedureType.
FILTER (lang(?procedureType) = "en")

?countryUri dc:identifier ?country.

}`

[cristianvasquez]

Hello,

I believe the query didn't work because of the hasProcurementObject property that doesn't appear to exist

In ePO, the CPV category can be retrieved through the 'Purpose' of a procedure. For example:

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX epo: <http://data.europa.eu/a4g/ontology#>
PREFIX cdm: <http://publications.europa.eu/ontology/cdm#>

SELECT *
WHERE {
  FILTER (?date = "2024-11-04"^^xsd:dateTime)
  FILTER (?formType = <http://publications.europa.eu/resource/authority/form-type/competition>)
  GRAPH ?noticeNamedGraph {
    ?noticeUri epo:hasPublicationDate ?date ;
               epo:hasFormType ?formType ;
               epo:refersToProcedure [
                  epo:hasPurpose [
          				epo:hasMainClassification <http://data.europa.eu/cpv/cpv/71200000>
      			  ]
              ] 
  }
}

Here is a link to an example that uses CPVs

I hope this helps,

[leobroom]

Thank you Cristian, this actually helps alot! The example works and would be a good example for the query library at https://data.ted.europa.eu/ or https://docs.ted.europa.eu/ODS/latest/snippets/index.html. I do not know why, but my searches always excluded the cpv-and-notices link, which explains how linked data can be queried really good. Thank you for taking time to answer my question in depth and giving my sanity back.

Greetings,
Leon

[VladimirAlexiev]

Hi @cristianvasquez and @leobroom !
Does this query take into account the hierarchical structure of CPV? I.e. that it should find not only procedures about 71200000, but all procedures about 712*****. Looking at http://data.europa.eu/cpv/cpv/71200000, I think you need to add skos:broader*:

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX epo: <http://data.europa.eu/a4g/ontology#>
PREFIX cdm: <http://publications.europa.eu/ontology/cdm#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT *
WHERE {
  FILTER (?date = "2024-11-04"^^xsd:dateTime)
  FILTER (?formType = <http://publications.europa.eu/resource/authority/form-type/competition>)
  GRAPH ?noticeNamedGraph {
    ?noticeUri epo:hasPublicationDate ?date ;
               epo:hasFormType ?formType ;
               epo:refersToProcedure/epo:hasPurpose/epo:hasMainClassification/skos:broader* <http://data.europa.eu/cpv/cpv/71200000>
  }
}

For some reason the query doesn't return anything, I'm trying to debug it.

[VladimirAlexiev]

The reason is GRAPH ?noticeNamedGraph: notice data lives in a named graph, but CPV data lives in the default graph.
When I remove that clause, the query returns a lot more than the original given by @cristianvasquez :

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX epo: <http://data.europa.eu/a4g/ontology#>
PREFIX cdm: <http://publications.europa.eu/ontology/cdm#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT *
WHERE {
  FILTER (?date = "2024-11-04"^^xsd:dateTime)
  FILTER (?formType = <http://publications.europa.eu/resource/authority/form-type/competition>)
    ?noticeUri epo:hasPublicationDate ?date ;
               epo:hasFormType ?formType ;
               epo:refersToProcedure/epo:hasPurpose/epo:hasMainClassification/skos:broader* <http://data.europa.eu/cpv/cpv/71200000>
}

[leobroom]

Thank you @VladimirAlexiev for the fix. I really appreciate, that you took the time for finding the cause.

Greetings,
Leon