statslite/build.gradle at master · Minecrell/statslite · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
plugins {
    id 'net.minecrell.licenser' version '0.3'
}

allprojects {
    group = 'net.minecrell.mcstats'
    version = '0.2.4-SNAPSHOT'

    apply plugin: 'java'
    apply plugin: 'eclipse'
    apply plugin: 'idea'

    sourceCompatibility = '1.7'
    targetCompatibility = '1.7'

    repositories {
        mavenCentral()
    }

    task sourceJar(type: Jar) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    task javadocJar(type: Jar, dependsOn: 'javadoc') {
        classifier = 'javadoc'
        from javadoc.destinationDir
    }

    artifacts {
        archives sourceJar
        archives javadocJar
    }

    apply plugin: 'maven-publish'

    publishing {
        publications {
            mavenJava(MavenPublication) {
                from components.java

                artifact sourceJar
                artifact javadocJar

                repositories {
                    maven {
                        url = System.getenv('REPO_' + (version.endsWith('-SNAPSHOT') ? 'SNAPSHOTS' : 'RELEASES')) ?: "$rootProject.buildDir/repo"
                    }
                }
            }
        }
    }

    apply plugin: 'net.minecrell.licenser'

    license {
        header = rootProject.file('LICENSE')
        include '**/*.java'
    }
}

subprojects {
    dependencies {
        compileOnly rootProject
    }

    jar {
        from rootProject.sourceSets.main.output
    }

    sourceJar {
        from rootProject.sourceSets.main.allSource
    }

    javadoc {
        source rootProject.sourceSets.main.java
    }
}

dependencies {
    compileOnly 'com.google.code.gson:gson:2.2.4'
}