ForgeGradle/build.gradle at FG_7.0 · MinecraftForge/ForgeGradle · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar

plugins {
    id 'java-gradle-plugin'
    id 'idea'
    id 'eclipse'
    id 'maven-publish'
    alias libs.plugins.gradleutils
    alias libs.plugins.gitversion
    alias libs.plugins.changelog
    alias libs.plugins.licenser
    alias libs.plugins.plugin.publish
    alias libs.plugins.shadow
}

gradleutils.displayName = 'ForgeGradle'
description = "Forge's Gradle plugin for Mod development"
group = 'net.minecraftforge'
version = gitversion.tagOffset

println "Version: $version"

java {
    toolchain.languageVersion = JavaLanguageVersion.of(17)
    withSourcesJar()
    withJavadocJar()
}

shadow {
    addTargetJvmVersionAttribute = false
}

gradleutils.pluginDevDefaults(configurations, libs.versions.gradle)

configurations {
    dependencyScope('runtimeCheckerOnly') {
        description = 'Contains the dependencies for the runtime environment checker used to check the Gradle version.'
    }

    resolvable('runtimeCheckerClasspath') {
        description = 'Contains the classpath for the runtime environment checker used to check the Gradle version.'
        transitive = false
        extendsFrom runtimeCheckerOnly
    }

    named('runtimeClasspath') {
        extendsFrom runtimeCheckerClasspath
    }
}

dependencies {
    runtimeCheckerOnly projects.runtimeEnvironmentCheck

    // Static Analysis
    api libs.annotations.jspecify

    // Gradle API
    compileOnly libs.gradle

    // GradleUtils Shared Base
    implementation libs.gradleutils.shared

    // Utils
    implementation libs.maven.artifact
    implementation libs.bundles.utils
}

license {
    header = rootProject.file('LICENSE-header.txt')
    newLine = false
    exclude '**/*.properties'
}

def includeRuntimeChecker = { Jar jar ->
    jar.dependsOn(configurations.runtimeCheckerClasspath.buildDependencies)
    jar.from(provider { zipTree(configurations.runtimeCheckerClasspath.singleFile) }) {
        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    }
}

tasks.named('jar', Jar) {
    includeRuntimeChecker(it)
    archiveClassifier = 'thin'
}

tasks.named('shadowJar', ShadowJar) {
    includeRuntimeChecker(it)

    enableAutoRelocation = true
    archiveClassifier = null
    relocationPrefix = 'net.minecraftforge.gradle.shadow'

    minimize()
    dependencies {
        exclude dependency(projects.runtimeEnvironmentCheck)
        exclude dependency(libs.annotations.jspecify)
    }
}

tasks.named('javadoc', Javadoc) {
    javadocTool = javaToolchains.javadocToolFor { languageVersion = JavaLanguageVersion.of(25) }
}

changelog {
    fromBase()
}

gradlePlugin {
    website = gitversion.url
    vcsUrl = gitversion.url + '.git'

    plugins.register('forgegradle') {
        id = 'net.minecraftforge.gradle'
        implementationClass = 'net.minecraftforge.gradle.internal.ForgeGradlePluginEntry'
        displayName = gradleutils.displayName.get()
        description = project.description
        tags = ['minecraftforge', 'minecraft']
    }
}

publishing {
    repositories {
        maven gradleutils.publishingForgeMaven
    }

    publications.register('pluginMaven', MavenPublication) {
        changelog.publish(it)
        gradleutils.promote(it)

        pom { pom ->
            name = gradleutils.displayName
            description = project.description

            gradleutils.pom.addRemoteDetails(pom)

            licenses {
                license gradleutils.pom.licenses.LGPLv2_1
            }

            developers {
                developer gradleutils.pom.developers.Jonathing
            }
        }
    }
}