build.gradle

plugins {
    id 'net.neoforged.moddev' version '2.0.112' apply false
}

subprojects {
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'
    apply plugin: 'idea'
    apply plugin: 'checkstyle'

    def isMod = project.findProperty('projectType') == 'mod'
    def isLibrary = project.findProperty('projectType') == 'library'

    // Only apply NeoForge plugin to mod projects, not libraries
    if (isMod) {
        apply plugin: 'net.neoforged.moddev'
    }

    checkstyle {
        toolVersion = '10.12.4'
        configFile = rootProject.file("config/checkstyle/google_checks.xml")
        configProperties = [
                'suppressionFile': rootProject.file("config/checkstyle/suppressions.xml")
        ]
        ignoreFailures = false
        maxWarnings = 0
    }

    tasks.withType(Checkstyle) {
        reports {
            xml.required = false
            html.required = true
        }
    }

    // Mojang ships Java 21 to end users in 1.21.1, so mods and libraries should target Java 21.
    java.toolchain.languageVersion = JavaLanguageVersion.of(21)

    repositories {
        mavenCentral()
        maven {
            name = 'NeoForged'
            url = 'https://maven.neoforged.net/releases/'
        }
    }

    // Determine version & group from mod or library properties if present
    if (isMod) {
        version = project.mod_version
        group = project.mod_group_id
    } else if (isLibrary) {
        version = project.lib_version
        group = project.lib_group_id
    }

    base {
        if (isMod) {
            archivesName = project.mod_id
        } else if (isLibrary) {
            archivesName = project.lib_id
        } else {
            archivesName = project.name
        }
    }

    // Only configure NeoForge for mod projects
    if (isMod) {
        neoForge {
            version = project.neo_version

            parchment {
                mappingsVersion = project.parchment_mappings_version
                minecraftVersion = project.parchment_minecraft_version
            }

            def runNamespace = project.mod_id
            def sharedRunDir = rootProject.file('run')

            runs {
                client {
                    client()
                    gameDirectory = sharedRunDir
                    systemProperty 'neoforge.enabledGameTestNamespaces', runNamespace
                }

                client2 {
                    client()
                    gameDirectory = sharedRunDir
                    programArguments.addAll '--username', 'Dev2'
                    systemProperty 'neoforge.enabledGameTestNamespaces', runNamespace
                }

                server {
                    server()
                    gameDirectory = sharedRunDir
                    programArgument '--nogui'
                    systemProperty 'neoforge.enabledGameTestNamespaces', runNamespace
                }

                gameTestServer {
                    type = "gameTestServer"
                    gameDirectory = sharedRunDir
                    systemProperty 'neoforge.enabledGameTestNamespaces', runNamespace
                }

                data {
                    data()
                    gameDirectory = sharedRunDir
                    programArguments.addAll '--mod', runNamespace, '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath()
                }

                configureEach {
                    systemProperty 'forge.logging.markers', 'REGISTRIES'
                    logLevel = org.slf4j.event.Level.DEBUG
                }
            }

            mods {
                "${mod_id}" {
                    sourceSet(sourceSets.main)
                }
            }
        }

        sourceSets.main.resources { srcDir 'src/generated/resources' }

        configurations {
            runtimeClasspath.extendsFrom localRuntime
        }

        dependencies {
            localRuntime "net.neoforged:neoforge:${neo_version}"
        }

        var generateModMetadata = tasks.register("generateModMetadata", ProcessResources) {
            var replaceProperties = [
                    minecraft_version: minecraft_version,
                    minecraft_version_range: minecraft_version_range,
                    neo_version: neo_version,
                    loader_version_range: loader_version_range,
                    mod_id: mod_id,
                    mod_name: mod_name,
                    mod_license: mod_license,
                    mod_version: mod_version,
                    mod_authors: mod_authors,
                    mod_description: mod_description
            ]
            inputs.properties replaceProperties
            expand replaceProperties
            from "src/main/templates"
            into "build/generated/sources/modMetadata"
        }

        sourceSets.main.resources.srcDir generateModMetadata
        neoForge.ideSyncTask generateModMetadata
    }

    // Common dependencies for all subprojects
    dependencies {
        compileOnly "net.neoforged:neoforge:${neo_version}"
    }

    // Add custom dependency extension for cleaner syntax
    dependencies.extensions.create('bundle', ModDependencyExtension, dependencies)

    publishing {
        publications {
            register('mavenJava', MavenPublication) {
                from components.java
                if (isMod) {
                    artifactId = project.mod_id
                } else if (isLibrary) {
                    artifactId = project.lib_id
                }
            }
        }
        repositories {
            maven {
                url "file://${project.projectDir}/repo"
            }
        }
    }

    tasks.withType(JavaCompile).configureEach {
        options.encoding = 'UTF-8'
    }

    tasks.withType(Checkstyle).configureEach {
        group = "verification"
    }

    idea {
        module {
            downloadSources = true
            downloadJavadoc = true
        }
    }
}

tasks.named('wrapper', Wrapper).configure {
    distributionType = Wrapper.DistributionType.BIN
}