shelf/build.gradle.kts at main · InvalidJoker/shelf · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
import java.util.Calendar

plugins {
    kotlin("jvm") version "2.2.21"
    kotlin("plugin.serialization") version "2.2.21"

    `java-library`
    `maven-publish`
    signing
}

group = "de.joker"

// Taken from https://github.com/TheFruxz/Stacked/blob/develop/build.gradle.kts
val publishVersion: String? = System.getenv("GH_RELEASE_VERSION")
val calendar: Calendar = Calendar.getInstance()
version = publishVersion ?: "${calendar[Calendar.YEAR]}.${calendar[Calendar.MONTH] + 1}-SNAPSHOT"

repositories {
    mavenCentral()
}

dependencies {
    testImplementation(kotlin("test"))
    implementation("org.jetbrains.kotlinx:kotlinx-serialization-json:1.9.0")
}

sourceSets {
    main {
        kotlin.srcDir("src")
    }
    test {
        kotlin.srcDir("test")
    }
}


tasks.test {
    useJUnitPlatform()
}

kotlin {
    jvmToolchain(21)
}

java {
    withSourcesJar()
    withJavadocJar()
}

publishing {
    publications {
        create<MavenPublication>("mavenJava") {
            from(components.findByName("java"))

            versionMapping {
                usage("java-api") {
                    fromResolutionOf("runtimeClasspath")
                }
                usage("java-runtime") {
                    fromResolutionResult()
                }
            }

            groupId = "dev.invalidjoker"
            artifactId = project.name
            version = project.version.toString()

            pom {
                name.set(project.name)
                description.set("Key/value object store for Kotlin. Persist any serializable object.")
                url.set("https://github.com/InvalidJoker/shelf")
                licenses {
                    license {
                        name.set("MIT License")
                        url.set("https://opensource.org/licenses/MIT")
                    }
                }
                developers {
                    developer {
                        id.set("invalidjoker")
                        name.set("InvalidJoker")
                    }
                }
            }
        }
    }

    repositories {
        val repoUrl = if (project.version.toString().endsWith("SNAPSHOT")) {
            "https://central.sonatype.com/repository/maven-snapshots/"
        } else {
            "https://ossrh-staging-api.central.sonatype.com/service/local/staging/deploy/maven2/"
        }
        maven {
            name = "sonatype"
            url = uri(repoUrl)
            credentials {
                username = findProperty("sonatypeUsername") as String?
                password = findProperty("sonatypePassword") as String?
            }
        }
    }
}

signing {
    sign(publishing.publications)
}