Some tools are missing English labels, even though they exist in Wikidata

[sopheck]

Example: https://furesh.github.io/toolfindr/tool/q83/

Until recently, the English label "MediaWiki" was still displayed. Now only the Q-ID "Q83" is shown.

However, the English label is present in Wikidata:

[sopheck]

This seems to be related to the new feature “default labels and aliases” for all languages:

For all empty labels, Wikidata now falls back to the default label. However, it appears that this default label cannot be queried via SPARQL using the usual en language code.

The following query for the English label returns the Q-ID instead of the default label:

PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX bd: <http://www.bigdata.com/rdf#>

SELECT ?item ?itemLabel WHERE {
  VALUES ?item { wd:Q83 }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Result in WDQS:

Solution:

The relevant Wikimedia help page mentions the following in the last FAQ entry:

How to show the default label in Wikidata Query Service (WDQS)?

If your SPARQL query uses the wikibase label service, change SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } into SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }.

If your SPARQL query uses the rdfs:label predicate, you can use the following code:

OPTIONAL { ?item rdfs:label ?labelEN. FILTER ( lang(?labelEN) = 'en' ) }
OPTIONAL { ?item rdfs:label ?labelMUL. FILTER ( lang(?labelMUL) = 'mul' ) }
BIND(COALESCE(?labelEN, ?labelMUL) AS ?itemLabel).

The key change is the addition of mul, which now has to be included in the language filter.

[sopheck]

The SPARQL query used to fetch the Wikidata data therefore needs to be adjusted:

Previous version:

...
SERVICE wikibase:label {
                bd:serviceParam wikibase:language "en" .
                ?tool rdfs:label ?label ;
                    schema:description ?description .
                ?instanceof rdfs:label ?instanceof_label .
                ?copyright rdfs:label ?copyright_label .
                ?license rdfs:label ?license_label .
            }
...

New:

...
SERVICE wikibase:label {
                bd:serviceParam wikibase:language "mul,en,[AUTO_LANGUAGE]" .
                ?tool rdfs:label ?label ;
                    schema:description ?description .
                ?instanceof rdfs:label ?instanceof_label .
                ?copyright rdfs:label ?copyright_label .
                ?license rdfs:label ?license_label .
            }
...

First fetch the default label with the language code mul, otherwise fall back to English or another (auto).