Cloudburst/build.gradle.kts at develop · CloudburstMC/Cloudburst · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
plugins {
    alias(libs.plugins.checkerframework) apply false
}

subprojects {
    apply(plugin = "java-library")
    if (name != "codegen") {
        apply(plugin = "maven-publish")
        apply(plugin = rootProject.libs.plugins.checkerframework.get().pluginId)

        configure<PublishingExtension> {
            repositories {
                maven {
                    name = "opencollab"
                    url = uri("https://repo.opencollab.dev/maven-snapshots")
                    credentials {
                        username = System.getenv("DEPLOY_USERNAME")
                        password = System.getenv("DEPLOY_PASSWORD")
                    }
                }
            }
        }
    }

    group = "org.cloudburstmc"
    version = rootProject.properties["$name.version"].toString()

    configure<JavaPluginExtension> {
        toolchain {
            languageVersion.set(JavaLanguageVersion.of(25))
        }
    }

    repositories {
        mavenCentral()
        maven("https://repo.opencollab.dev/maven-releases")
        maven("https://repo.opencollab.dev/maven-snapshots")
    }

    dependencies {
        "compileOnly"(rootProject.libs.lombok)
        "annotationProcessor"(rootProject.libs.lombok)

        "compileOnly"(rootProject.libs.checker.qual)

        "testAnnotationProcessor"(rootProject.libs.lombok)
        "testImplementation"(rootProject.libs.lombok)
    }

    tasks {
        withType<JavaCompile> {
            options.encoding = "UTF-8"
        }

        withType<Test> {
            useJUnitPlatform()
        }
    }
}