MOVESMRG crashed when MTMP_OUTPUT_YN = Y

[hnqtran]

This issue was reported by a SMOKE user which was ultimately traced back to setting of MTMP_OUTPUT_YN = Y in onroad RPD run script for onroad_ca sector. Setting MTMP_OUTPUT_YN = N solved the issue that the user was having.

Further investigation revealed that the issue was replicable in latest SMOKE version 5.2.1 and on current EPA EMP 2022v1. However, setting MTMP_OUTPUT_YN = Y alone would not cause MOVESMRG to crash; it is the combine with setting of USE_SPCMAT_SPC_YN = N (if undefined, take default value = N) that caused the crash

The crash is traced back to out-of-bound issue (Fortran runtime error: Index '0' of dimension 2 of array 'mtmp_invt' below lower bound of 1) within this code block in src/movesmrg/movesmrg.f:

                            IF( MTMP_OUT ) THEN
                                IF( SMATCHK ) THEN
                                    IF( EANAMREP( V ) ) THEN
                                        MTMP_INVT( SRC,SIIDX,T ) =
     &                                       MTMP_INVT( SRC,SIIDX,T ) +
     &                                       EMVAL * GM2TON       ! g/hr-cell * ton/g = ton/hr-cell
                                    END IF
                                ELSE
                                    MTMP_INVT( SRC,SIIDX,T ) =
     &                                   MTMP_INVT( SRC,SIIDX,T ) +
     &                                   EMVAL * GM2TON       ! g/hr-cell * ton/g = ton/hr-cell
                                END IF
                            END IF

In this case, for some reason SRC was assigned with zero which violate the minimum bound of 1. Further analyses is still pending.

[hnqtran]

Update:
Array Dimensions: The array MTMP_INVT is allocated as (NMSRC, NIPPA, NSTEPS) (where NIPPA is the number of inventory pollutants).
In the merged output loop, SMOKE iterates through all pollutant-species combinations (V = 1 to NPOLSPC). When USE_SPCMAT_SPC_YN = N (meaning SMATCHK = .FALSE.), NPOLSPC is the sum of inventory pollutants and model species (NIPPA + NMSPC). For the first NIPPA entries (pollutants), SIIDX is valid (1 to NIPPA). For entries V > NIPPA (model species), SIIDX remains initialized to 0.

Inside the MTMP_OUT block (around line 1134), the code attempts to update MTMP_INVT(SRC, SIIDX, T) for every V without checking if it's a pollutant or species:

1133:                                 ELSE
1134:                                     MTMP_INVT( SRC,SIIDX,T ) =
1135:      &                                   MTMP_INVT( SRC,SIIDX,T ) +
                                        ...

When processing a species (V > NIPPA), SIIDX is 0, which violates the lower bound of dimension 2 (the pollutant dimension).

The fix involves wrapping the MTMP_INVT update in a check to ensure it only executes for inventory pollutants (V <= NIPPA). Specifically, wrap the MTMP_INVT accumulation block for the SMATCHK = .FALSE. case with an IF( V <= NIPPA ) statement to prevent accessing the array with index 0 when processing model species.

                            IF( MTMP_OUT ) THEN
                                IF( SMATCHK ) THEN
                                    IF( EANAMREP( V ) ) THEN
                                        MTMP_INVT( SRC,SIIDX,T ) =
     &                                       MTMP_INVT( SRC,SIIDX,T ) +
     &                                       EMVAL * GM2TON
                                    END IF
                                ELSE
                                    ! ADDED CHECK: Only update for pollutants
                                    IF( V <= NIPPA ) THEN
                                        MTMP_INVT( SRC,SIIDX,T ) =
     &                                       MTMP_INVT( SRC,SIIDX,T ) +
     &                                       EMVAL * GM2TON
                                    END IF
                                END IF
                            END IF