lviz/CMakeLists.txt at main · AnthonyK213/lviz · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
cmake_minimum_required(VERSION 3.20)

project(
  lviz
  VERSION 0.0.1
  LANGUAGES C CXX
  )

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
set(CMAKE_CXX_EXTENSIONS OFF)
set(CMAKE_POLICY_DEFAULT_CMP0077 NEW)
set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/cmake" ${CMAKE_MODULE_PATH})
set(CMAKE_INSTALL_PREFIX ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-${PROJECT_VERSION})

### Require out-of-source builds
file(TO_CMAKE_PATH "${PROJECT_BINARY_DIR}/CMakeLists.txt" LOC_PATH)
if(EXISTS "${LOC_PATH}")
  message(FATAL_ERROR "You cannot build in a source directory
  (or any directory with a CMakeLists.txt file). Please make a
  build subdirectory. Feel free to remove CMakeCache.txt and CMakeFiles.")
endif()

if(WIN32)
  option(BUILD_SHARED_LIBS "Build using shared libraries" ON)
else()
  option(BUILD_SHARED_LIBS "Build using shared libraries" OFF)
endif()

option(LVIZ_ENABLE_ASAN "Enable AddressSanitizer" OFF)
if(LVIZ_ENABLE_ASAN)
  message(STATUS "AddressSanitizer (ASan) is enabled.")
  if(MSVC)
    add_compile_options(/fsanitize=address /Zi)
    add_link_options(/fsanitize=address)
    set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreadedDLL")
  else()
    add_compile_options(-fsanitize=address -fno-omit-frame-pointer)
    add_link_options(-fsanitize=address)
  endif()
endif()

set(OpenGL_GL_PREFERENCE "GLVND")

# find_package(OpenGL REQUIRED)
# message("OpenGL: ${OPENGL_gl_LIBRARY}")

set(LUAJIT_DIR ${CMAKE_BINARY_DIR}/deps/LuaJIT_Source CACHE STRING "Path of LuaJIT 2.1 source dir")

include(cmake/FetchGLFW.cmake)
include(cmake/FetchGLM.cmake)
include(cmake/FetchImGui.cmake)
include(cmake/FetchLuaJIT.cmake)
include(cmake/FetchLuaBridge3.cmake)
include(cmake/FetchFreeType.cmake)
include(cmake/FetchFonts.cmake)

if(${LVIZ_ENABLE_FENNEL_SUPPORT})
  include(cmake/FetchFennel.cmake)
endif()

# GLAD
set(GLAD_DIR ${CMAKE_SOURCE_DIR}/deps/glad)
add_library(glad STATIC ${GLAD_DIR}/src/glad.c)
target_include_directories(glad PUBLIC ${GLAD_DIR}/include/)

# ImGui
set(IMGUI_DIR ${CMAKE_BINARY_DIR}/deps/imgui)
add_library(
  imgui
  STATIC
  ${IMGUI_DIR}/imgui.cpp
  ${IMGUI_DIR}/imgui_draw.cpp
  ${IMGUI_DIR}/imgui_tables.cpp
  ${IMGUI_DIR}/imgui_widgets.cpp
  ${IMGUI_DIR}/backends/imgui_impl_glfw.cpp
  ${IMGUI_DIR}/backends/imgui_impl_opengl3.cpp
  )
target_include_directories(
  imgui
  PUBLIC
  ${IMGUI_DIR}
  ${IMGUI_DIR}/backends/
  ${glfw_SOURCE_DIR}/include/
  )

# lviz
add_subdirectory(src)