elegantarmour/build.gradle at main · AmyMialeeMods/elegantarmour · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
plugins {
    id 'fabric-loom' version '1.10-SNAPSHOT'
    id 'maven-publish'
    id "me.modmuss50.mod-publish-plugin" version "0.8.4"
}

base {
    archivesName = project.mod_id + "-" + project.minecraft_version
}

version = project.mod_version
group = project.maven_group

repositories {
    maven { url "https://maven.terraformersmc.com/" }
    maven { url "https://maven.willbl.dev/releases" }
    maven { url "https://maven.ladysnake.org/releases" }
    maven { url "https://repo.unascribed.com" }
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
    modImplementation "com.terraformersmc:modmenu:${project.modmenu_version}"

    modImplementation include("xyz.amymialee:mialib:${project.mialib_version}")
    modImplementation include("org.ladysnake.cardinal-components-api:cardinal-components-base:${project.cca_version}")
    modImplementation include("org.ladysnake.cardinal-components-api:cardinal-components-entity:${project.cca_version}")
    implementation ("com.unascribed:ears-api:1.4.5")
}

loom {
    accessWidenerPath = file("src/main/resources/${project.mod_id}.accesswidener")
}

fabricApi {
    configureDataGeneration() {
        modId = project.mod_id
        client = true
    }
}

publishMods {
    file = remapJar.archiveFile
    additionalFiles.files.add(remapSourcesJar.archiveFile.get().getAsFile())
    displayName = "${project.version.toString().split("\\+")[0]} for $minecraft_version"
    changelog = ""
    type = STABLE
    modLoaders.addAll("fabric", "quilt", "neoforge")
    dryRun = !providers.gradleProperty("curseforge_api_key").isPresent() || !providers.gradleProperty("modrinth_api_key").isPresent()
    curseforge {
        accessToken = providers.gradleProperty('curseforge_api_key')
        projectId = curseforge_id
        minecraftVersionRange {
            start = minecraft_version
            end = minecraft_version
        }
        announcementTitle = "Download from CurseForge"
        javaVersions.addAll(JavaVersion.VERSION_21, JavaVersion.VERSION_22)
        clientRequired = false
        serverRequired = true
        projectSlug = curseforge_slug
        requires("fabric-api")
        embeds("cardinal-components-api")
    }
    modrinth {
        accessToken = providers.gradleProperty("modrinth_api_key")
        projectId = modrinth_id
        minecraftVersionRange {
            start = minecraft_version
            end = minecraft_version
            includeSnapshots = true
        }
        announcementTitle = "Download from Modrinth"
        requires("fabric-api")
        embeds("cardinal-components-api")
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }
    repositories {
        maven {
            name = "willBlRepositoryReleases"
            url = "https://maven.willbl.dev/releases"
            credentials(PasswordCredentials)
            authentication {
                basic(BasicAuthentication)
            }
        }
    }
}

processResources {
    inputs.property "version", project.version
    filteringCharset "UTF-8"
    filesMatching("neoforge.mods.toml") {expand "version": project.version}
    filesMatching("fabric.mod.json") {expand "version": project.version}
}

tasks.withType(JavaCompile).configureEach {
    it.options.encoding = "UTF-8"
    it.options.release.set(21)
}

java {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
    toolchain.languageVersion = JavaLanguageVersion.of(21)
    withSourcesJar()
}

jar {
    from("LICENSE.md") {
        rename { "${it}_${project.archivesBaseName}" }
    }
}